Restaurar la configuración de Vista de carpetas en Windows 10

El Explorador de archivos de Windows es fácil de navegar y viene con muchas características de accesibilidad interesantes. Una de las que seguramente agradará a la mayoría de los usuarios es la Vista de carpetas. Gracias a ésta, incluso, podemos personalizar nuestras carpetas para representar el tipo de archivos que cada una contiene. Pues bien, en este artículo queremos enseñarte cómo hacer una copia de seguridad y restaurar la configuración de Vista de carpetas en Windows 10. Estamos convencidos de que te será de gran ayuda.

Como decíamos, gracias a este sistema tendrás la posibilidad de personalizar cada carpeta. No sólo para que muestra iconos grandes, medianos o chicos. Sino, además, para que esos iconos sean acordes a los elementos que se hallan dentro de las mismas. El asunto es que, tras realizar estas modificaciones, probablemente querrás realizar una copia de seguridad para guardar todo y, así, evitar perder tus cambios.

Por eso mismo, queremos enseñarte de qué modo hacer una copia de seguridad y restaurar la configuración de Vista de carpetas en Windows 10. Presta atención porque vamos con el paso a paso en cuestión:

Copia de seguridad y restaurar la Vista de carpetas paso a paso

Crear el archivo de copia de seguridad y restauración

En tu ordenador, busca la aplicación de Bloc de notas, y copia esto:

@ECHO OFF

title Backup and Restore Folder View Settings Tool
:choice
cls
echo.
echo OPTIONS:
echo.
echo 1. Back up your folder view settings.
echo 2. Restore folder view settings from backup.
echo 3. Cancel
echo.
echo.
set /P c=Type the option number you would like to do, and press Enter?
if /I "%c%" EQU "1" goto :verify1
if /I "%c%" EQU "2" goto :verify2
if /I "%c%" EQU "3" exit
goto :choice

:verify1
IF EXIST "%userprofile%\Desktop\Folder View Settings Backup" goto :response1
goto :backup

:response1
echo.
echo.
echo You already have a "Folder View Settings Backup" folder on your desktop.
echo Please move it to another location, and try again.
echo.
pause
goto :choice

:backup
mkdir "%userprofile%\Desktop\Folder View Settings Backup"
REG EXPORT HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Streams\Defaults "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_CurrentVersion_Explorer_Streams_Defaults.reg" /y
REG EXPORT HKCU\Software\Microsoft\Windows\Shell\BagMRU "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_BagMRU.reg" /y
REG EXPORT HKCU\Software\Microsoft\Windows\Shell\Bags "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_Bags.reg" /y
REG EXPORT HKCU\Software\Microsoft\Windows\ShellNoRoam\Bags "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_Bags.reg" /y
REG EXPORT HKCU\Software\Microsoft\Windows\ShellNoRoam\BagMRU "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_BagMRU.reg" /y
REG EXPORT "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_BagMRU.reg" /y
REG EXPORT "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_Bags.reg" /y
cls
echo.
echo Backup of folder view settings successfully completed.
echo.
pause 
exit

:verify2
IF NOT EXIST "%userprofile%\Desktop\Folder View Settings Backup" goto :response
goto :restore

:response
echo.
echo.
echo You do not have a "Folder View Settings Backup" folder on your desktop.
echo Please place the backup folder on your desktop, and try again.
echo.
pause
goto :choice

:restore 
REG Delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Streams\Defaults" /F
Reg Delete "HKCU\Software\Microsoft\Windows\Shell\BagMRU" /F
Reg Delete "HKCU\Software\Microsoft\Windows\Shell\Bags" /F
Reg Delete "HKCU\Software\Microsoft\Windows\ShellNoRoam\Bags" /F
Reg Delete "HKCU\Software\Microsoft\Windows\ShellNoRoam\BagMRU" /F
Reg Delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" /F
Reg Delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" /F

REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_CurrentVersion_Explorer_Streams_Defaults.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_BagMRU.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_Bags.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_Bags.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_BagMRU.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_BagMRU.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_Bags.reg"
cls
echo.
echo Backup of folder view settings successfully restored.
echo.
echo Waiting to restart explorer to apply.
echo Your screen will flash as explorer is restarted.
echo.
echo.
pause
taskkill /f /im explorer.exe
start explorer.exe 
exit

Luego, guarda el archivo en tu escritorio con la extensión .bat. Para hacerlo, sólo tienes que asignarle un nombre que te recuerde de qué se trata y, antes de darle al botón Guardar, agregarle el «.bat». Esto te permitirá guardar los archivos por lotes y, cuando los ejecutas, que se ejecuten comandos completos.

Desbloquear el archivo .bat

Después de guardar con éxito el archivo recién creado como un archivo .bat, puedes encontrarte con que Windows lo haya bloqueado. Suele suceder. Por eso mismo, el primer paso consistirá en desbloquearlo. Para hacerlo, tienes que hacer click con el botón derecho en el archivo, seleccionando Propiedades dentro del menú contextual.

Allí cambia a la pestaña General de la ventana Propiedades, y busca la casilla de verificación que refiere a Desbloquear, en la parte inferior de la misma. Marca esta casilla, y presiona el botón Aceptar para desbloquear el archivo por lotes. (Si no ves esta casilla, eso significa que Windows no bloqueó el archivo. No te preocupes)

Ejecutar el archivo .bat

Una vez que hayas desbloqueado el archivo .bat, podríamos decir que estarás listo para comenzar con el procedimiento en su parte final. Primero que nada, tienes que hacer doble click sobre el mismo para ejecutarlo. La ejecución de este archivo por lotes abrirá una ventana del Símbolo del sistema, con algunas opciones disponibles:

• Hacer una copia de seguridad de la configuración de la Vista de carpetas
• Restaurar la configuración de la Vista de carpetas desde la copia de seguridad
• Cancelar

Si quieres hacer una copia de seguridad de la configuración de la Vista de carpetas, presiona 1 y luego la tecla Enter. Mientras tanto, si pretendes restaurar la configuración de Vista de carpetas, presiona 2 y luego Enter,

En caso de que este artículo te haya resultado atractivo, probablemente querrás saber cómo cambiar los iconos de apps y carpetas en una Mac. Después de todo, los ordenadores de Apple también admiten cierta personalización.